Solar Float Battery Charger

This charger tries to match the power output of the solar panel to the battery to get the most energy into it. It will also not let the battery get above a voltage (13.8v) as set by the variable resistor.

The charger has a boost regulator in it to allow solar panels of a lower voltage than the battery to charge it.

# Setting the maximum voltage to charge the battery to

Carefully adjust the potentiometer (white knob with Philips head screw) inside the box – it is quite sensitive. Measure the battery voltage carefully over the next while to check.

# How it works

The voltage regulator (IC2) provides power to a PICAXE 08M2 microcontroller (IC1). The PICAXE measures the solar panel open circuit voltage (or fairly close to it) through the voltage divider on the panel side (R1 and R2). It then multiplies this by 80% to get something fairly close the Maximum Power Point (MPP), where the voltage multiplied by the current produces the most power. This charger cannot measure current, so this is the quickest and easiest way of attempting to find it.

The chip will then put a Pulse Width Modulation (PWM) signal to turn the MOSFET on and off, which then draws and interrupts current in the inductor. This creates spikes in the voltage, which are fed through a diode (D1) into a capacitor(C4), where they are stored. The battery is charged through a second diode (D3). The PICAXE varies the duty cycle of the PWM signal to vary how much energy goes through the boost regulator to try to keep the solar panel voltage at the MPP as it determined previously.

To stop the battery from being overcharged, the chip measures the voltage being put into the battery and turns off the regulator when it reaches a threshold, measured through the voltage divider on the battery side (R7 and R8), of which the potentiometer is part of (R8). The charger will wait a few seconds (taking advantage of the time to work out the maximum power point again in case it has changed) before charging again. – It will often only charge for fractions of a second before the voltage goes up enough for the battery to be charged and it will repeat.

The charger also stops charging for a few seconds once every 5 minutes to recalculate the MPP in case it has changed.

The LED (LED1) flashes on start up, when maximising and when sending serial data that a computer could pick up if one is connected. The LED also flashes when the battery is disconnected as it treats the storage capacitor as an extremely small battery and charges it so quickly that it spends most of its time maximising.

Serial communication is achieved with a standard PICAXE programming cable or similar (may require an adapter to convert from an audio jack to the 3 pin header (JP1)) and a serial terminal / reader set to 38400 baud, no parity, 8 data bits and one stop bit.

This charger will not work properly with solar panels that have a significantly higher (more than a few volts) open circuit voltage than the battery as the charger has no way of actually completely disconnecting the battery and solar panel other than using diodes and relying on the battery voltage being higher or close enough that the solar panel cannot push current through it when the boost regulator is not running, possibly overcharging the battery and interfering with the way the charger works out the optimum voltage to get the most power from the panel (the Maximum Power Point, or MPP). If you want to use this for higher voltage panels, you will need to convert it to a buck regulator.

# Design Specifications

|  |  |
| --- | --- |
| Solar Panel: | 14V OCV, 1.5A Max Short Circuit, Around 11V MPP. Polycrystalline silicon. – Probable a little too higher voltage, but that was what was around. |
| Battery: | 12V 6 Cell Lead Acid Battery. |

'Switchmode power supply

'pins

symbol led = c.0

symbol voltsOut = c.1

symbol mosfet = c.2

symbol voltsIn = c.4

'variables

symbol batteryVoltage = b0

symbol solarVoltage = b3

symbol currentDuty = w12

symbol mppVoltage = w13


'constants

symbol dutyMin = 0 '0% duty cycle at 4MHz clock at 15094Hz

symbol dutyMax = 265 '50% duty cycle at 4MHz clock at 15094Hz

symbol batMax = 140 '13.8 - adjust pot to be this

symbol batMin = 135 'Roughly 13v to start charging again

init:

setfreq m32

sertxd("Started", 13, 10)

high led

pause 16000

low led

pause 24000

readadc voltsIn, solarVoltage

sertxd("Initial OCV: ", #solarVoltage, 13, 10)

currentDuty = dutymin

pwmout pwmdiv4, mosfet, 132, currentDuty

gosub mpp

main:

'Maximum Power Point Tracker part

readadc voltsIn, solarVoltage

if solarVoltage < mppVoltage then

if currentDuty > dutyMin then

currentDuty = currentDuty - 1

endif

endif

if solarVoltage > mppVoltage then

if currentDuty < dutyMax then

currentDuty = currentDuty + 1

endif

endif

'Battery monitoring part

readadc voltsOut, batteryVoltage

if batteryVoltage >= batMax then gosub batCharged

'Change MOSFET duty cycle

pwmduty mosfet, currentDuty

if currentDuty = dutyMax then

high led

else

low led

endif

'Recalibrate mpp every 300 seconds (time increment every 0.5 seconds at 32MHz

if time > 600 then gosub mpp

goto main

batCharged:

sertxd("Battery Charged", 13, 10)

currentDuty = dutyMin

pwmduty mosfet, currentDuty

do

toggle led

pause 8000

readadc voltsOut, batteryVoltage

sertxd("Voltage: ", #batteryVoltage, 13, 10)

loop while batteryVoltage > batMin

gosub mpp

return

mpp:

sertxd("Maximising",13,10)

currentDuty = dutyMin

pwmduty mosfet, currentDuty

high led

pause 20000

low led

pause 20000

readadc voltsIn, mppVoltage

sertxd("OCV: ", #mppVoltage)

mppVoltage = mppVoltage \* 8 / 10 'MPP is roughly 80% of OCV

sertxd("\tMPP: ", #mppVoltage, 13, 10, 13, 10)

gosub resetTime

return

resetTime:

disabletime

time = 0

enabletime

return